Backups sind nicht nur für die lokalen Daten wichtig, sondern auch für das eigene Blog. Wie schon zuvor in einem eigenen Artikel beschrieben, nutze ich das WordPress Database Backup Plug-In. Das schickt mir einmal in der Woche ein Backup per Mail.
Damit das ordentlich aufgeräumt wird, habe ich mir für Apple Mail ein AppleScript geschrieben, das dafür sorgt. Es kopiert den Anhang auf die Festplatte und löscht die E-Mail.
Hier ist das Script:
using terms from application "Mail"
on perform mail action with messages theMessages for rule theRule
-- hier den Ordner eintragen, in dem das Backup abgelegt werden soll:
set theOutputFolder to "Macintosh HD:Users:IhrBenutzername:Documents:"
tell application "Mail"
set theMessage to item 1 of theMessages
set theAttachments to every mail attachment of theMessage
repeat with a from 1 to length of theAttachments
set theAttachment to item a of theAttachments
try
set theAttName to name of theAttachment
set theSavePath to theOutputFolder & theAttName
save theAttachment in theSavePath
-- E-Mail in Papierkorb verschieben
set mailbox of theMessage to mailbox "Trash"
on error
beep 2
-- Wer Growl nicht verwendet, lässt diese Zeile weg:
my GrowlMe("Fehler beim Ablegen der WordPress DB.")
return -- Ausführung abbrechen
end try
end repeat
end tell
-- Wer Growl nicht verwendet, lässt diese Zeile weg:
my GrowlMe("WordPress DB erfolgreich abgelegt.")
end perform mail action with messages
end using terms from
-- Benachrichtigung via Growl, nicht unbedingt nötig
on GrowlMe(myMsg)
tell application "GrowlHelperApp"
set the allNotificationsList to {"Wordpress-Backups"}
set the enabledNotificationsList to {"Wordpress-Backups"}
register as application ¬
"Wordpress-Backups" all notifications allNotificationsList ¬
default notifications enabledNotificationsList ¬
icon of application "Safari"
notify with name ¬
"Wordpress-Backups" title "Wordpress-Backups" description myMsg ¬
application name "Wordpress-Backups"
end tell
end GrowlMe
Das Script können Sie mit dem Programm AppleScript-Editor (in Standardinstallation von OS X enthalten) als .scpt-Datei abspeichern unter Macintosh HD:Users:IhrBenutzername:Library:Scripts:Applications:Mail:Rule - SaveAttatchment.scpt.
Dann öffnen Sie Mail und wählen Sie bei „Mail/Einstellungen“ den Punkt „Regeln“ aus. Klicken Sie auf „Regel hinzufügen“.
Stellen Sie die Bedingungen ein wie im Screenshot zu sehen und wählen Sie unten per Klick auf „Auswählen“ das eben gespeicherte Script aus.
Wichtig: Setzen Sie die Regel möglichst weit nach oben, wenn sie noch andere haben. Denn sonst kann es sein, dass die Mail mit dem Backup von einer anderen Regel bearbeitet wird und daher unserer eben definierten entwischt.
